[General] Linked Open Data - demo

• Piotr Hołda, Tomasz Szymula

Co możemy ciekawego znaleźć w Linked Open Data? Jak te dane się ze sobą łączą? Kilkanaście przypadków użycia (zapytania SPARQL) łączących różne zbiory danych.

• min. 15 przykładów, każdy wg schematu:
  • pomysł na to co chcemy osiągnąć
  • wykorzystywane zbiory danych (bardzo krótko) + co z nich wyciągamy i dlaczego
  • zapytanie SPARQL
    • najlepiej parametryzowane: użytkownik coś podaje, np. nazwę zespołu muzycznego / swoją lokalizację (wyciągniętą z modułu GPS) i na ten temat szukamy informacji i łączymy je ze sobą
  • otrzymane wyniki (wystarczy tabela zwracana przez jakiś silnik SPARQL, np. Twinkle)
  • interpretacja wyników (jeżeli nie są trywialne i nagłówki tabeli wynikowej nie pomagają)
• (co najmniej) 5 przykładów łączy informację z 3 lub więcej źródeł
• wykorzystywane jest co najmniej 15 różnych zbiorów danych

Część zapytań robiona była z wykorzystaniem Twinkle, część poprzez interfejsy SPARQL (endpoint). Natomiast najlepszym narzędziem okazało się YASGUI.

• Wyszukanie najmniejszych krajów na świecie
  • zbiór danych to Cia World Factbook. Zawiera on informacje o historii, narodach, rządach, ekonomii itp. 267 krajów.
  • zapytanie SPARQL:

    SELECT ?name ?area WHERE{
    ?country factbook:countryname_conventionalshortform ?name .
    ?country factbook:area_total ?area .
    FILTER ( xsd:decimal(?area) < 100 )
    }
    ORDER BY ?area

  • wyniki

• Informacje o obozach koncentracyjnych
  • zbiór danych “Shoah victims’ names”
  • zapytanie SPARQL:

    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    
    select distinct ?label ?type where {
      ?a a <http://dati.cdec.it/lod/shoah/NaziCamp>;
        rdfs:label ?label;
        rdf:type ?type.
    }

  • wyniki:

• Wybranie ludzkich genów znajdujących się w chromosimie Y
  • Zbiór danych: linkedlifedata
  • Zapytanie:

    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
            PREFIX gene: <http://linkedlifedata.com/resource/entrezgene/>
            PREFIX uniprot: <http://purl.uniprot.org/uniprot/core/>
            PREFIX core: <http://purl.uniprot.org/core/>
    
            SELECT ?genedescription ?taxonomy
            WHERE {
                ?geneid gene:description ?genedescription .
                ?geneid gene:uniprotAccession ?uniprotaccession .
                ?geneid gene:chromosome 'Y' .
                ?uniprotaccession core:organism ?taxonomy .
                ?taxonomy core:scientificName 'Homo sapiens' .
            }

  • wyniki:

• Informacje o stacjach meteorologicznych
  • Zbiór danych: AEMET metereological dataset
  • Zapytanie

    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
    prefix aemetonto: <http://aemet.linkeddata.es/ontology/>
    
    select ?stationName ?lat ?long where {
      ?a a aemetonto:WeatherStation;
        aemetonto:stationName ?stationName;
        geo:location ?location.
      ?location geo:lat ?lat;
        geo:long ?long.
    } limit 1000 

    • Wyniki

• Uzyskanie informacji o zawartości tłuszczu w różnych posiłkach
  • zbiór danych z world.openfoodfacts.org. Zawiera informacje o składzie sposiłków, ocenach itp.
  • Zapytanie SPARQL

    SELECT ?name ?fat WHERE {
    ?product food:fatPer100g ?fat .
    ?product food:name ?name .
    }
    LIMIT 5

  • wyniki

• Informacje o aktach prawnych dotyczących EWWiS
  • Zbiór danych: PreLex
  • Zapytanie SPARQL

    select ?title ?date where {
      ?a a <http://eur-lex.publicdata.eu/ontology/Agreement>;
        <http://eur-lex.publicdata.eu/ontology/Treaty> <http://eur-lex.publicdata.eu/ontology/European+Coal+And+Steel+Community>;
        <http://eur-lex.publicdata.eu/ontology/title> ?title;
        <http://eur-lex.publicdata.eu/ontology/date_document> ?date.
    } limit 100

  • wyniki

• Informacje o językach, ich kodach
  • Zbiór danych lingvoj.org
  • Zapytanie

    SELECT ?label ?code2 ?code3 WHERE {
    ?lingvo rdfs:label ?label .
    ?lingvo lvont:iso639P1Code ?code2 .
    ?lingvo lvont:iso639P2BCode ?code3 .
    }
    LIMIT 5

  • wyniki

• Austriaccy narciarze alpejscy
  • zbiór danych z vocabulary.semantic-web.at/AustrianSkiTeam.html
  • zapytanie:

    SELECT ?name WHERE {
    ?l skos:prefLabel ?name;
    }

  • wyniki:

• Dostępne książki w języku fińskim w Projekcie Gutenberg
  • zbiór danych to metadane dostępne w “Project Gutenberg” na temat książek nie ograniczonych licencjami.
  • Zapytanie SPARQL

    SELECT DISTINCT ?label ?lang WHERE {
      ?a rdfs:label ?label.
      ?a dc:language ?lang.
      filter (?lang = "fi")
    
    }
    LIMIT 5

  • wyniki

• Programy UE dotyczące równego traktowania
  • Zbiór danych: N-lex
  • Zapytanie SPARQL

    select * where {
      ?a a <http://eur-lex.publicdata.eu/ontology/Programme>;
        <http://eur-lex.publicdata.eu/ontology/eurovoc_descriptor> <http://eur-lex.publicdata.eu/id/equal+treatment>;
        <http://eur-lex.publicdata.eu/ontology/title> ?title
    } limit 100 

  • Wyniki

• Dowiedzieć się jakie lekarstwa/narkotyki nie oddziałujące na zwierzęta i ludzi są nielegalne
  • Zbiór danych: Bio2RDF::Drugbank
  • zapytanie SPARQL:

    PREFIX void: <http://rdfs.org/ns/void#>
    PREFIX dv: <http://bio2rdf.org/bio2rdf.dataset_vocabulary:>
    PREFIX dbv: <http://bio2rdf.org/drugbank_vocabulary:>
    SELECT ?title, ?group, ?ao
    WHERE {
    ?a a dbv:Drug;
     dbv:group ?group;
     dbv:affected-organism ?ao;
     dcterms:title ?title.
    filter (?group = dbv:Illicit).
    filter (?ao != dbv:Humans-and-other-mammals).
    }

  • wyniki: brak
  • wnioski: tylko ludzie i zwierzęta są prawnie chronieni przed następstwami lekarstw/narkotyków.

• aktorzy grający w filmach przygodowych
  • zbiór danych: Linked Movie DataBase
  • zapytanie SPARQL:

    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
    PREFIX movie: <http://data.linkedmdb.org/resource/movie/>
    PREFIX owl: <http://www.w3.org/2002/07/owl#>
    
    
    select distinct ?actor ?name where {
      ?m a movie:film;
        movie:genre <http://data.linkedmdb.org/resource/film_genre/31>;
        movie:actor ?actor.
      ?actor rdfs:label ?name.
    }

  • wyniki:

• Licencje zezwalające na kopiowanie
  • zbiór danych: http://purl.org/NET/rdflicense (informacje w formie RDF nt 126 licencji)
  • zapytanie SPARQL

    PREFIX odrl: <http://www.w3.org/ns/odrl/2/>
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    select ?l where {
      ?l a <http://www.w3.org/ns/odrl/2/Set>;
        odrl:permission ?node.
      ?node odrl:action <http://www.w3.org/ns/odrl/2/copy>.
    }

  • wyniki

• Informacje o ostatnich laureatach nagrody Nobla w powiązaniu z informacjami o krajach pochodzenia
  • zbiór danych to http://dbpedia.org, eurostat i nobelprize.org
  • zapytanie SPARQL

    PREFIX owl: <http://www.w3.org/2002/07/owl#>
    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    PREFIX dbpedia: <http://dbpedia.org/>
    PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    PREFIX nobel: <http://data.nobelprize.org/terms/>
    PREFIX eurostat: <http://wifo5-04.informatik.uni-mannheim.de/eurostat/resource/eurostat/>
    PREFIX dbpprop: <http://dbpedia.org/property/>
    
    select distinct ?laureat ?year ?country ?populationCensus ?death_rate ?electricity_consumption_GWh ?electricity_production_capacity_MWh  where {
      service <http://dbpedia.org/sparql> {
        ?countryx a <http://dbpedia.org/ontology/Country> ;
          dcterms:subject <http://dbpedia.org/resource/Category:Member_states_of_the_European_Union>.
        OPTIONAL {?countryx dbpprop:populationCensus ?populationCensus }.
      }.
      service <http://wifo5-04.informatik.uni-mannheim.de/eurostat/sparql> {
        ?countryz owl:sameAs ?countryx.
          OPTIONAL {?countryz eurostat:death_rate ?death_rate }.
          OPTIONAL {?countryz eurostat:electricity_consumption_GWh ?electricity_consumption_GWh}.
          OPTIONAL {?countryz eurostat:electricity_production_capacity_MWh ?electricity_production_capacity_MWh}.
      }.
      ?a rdf:type <http://data.nobelprize.org/terms/Laureate>;
        rdfs:label ?laureat;
        nobel:laureateAward ?award.
      ?award nobel:year ?year.
      ?a dbpedia-owl:birthPlace ?country.
      ?country a <http://dbpedia.org/ontology/Country>.
      ?country owl:sameAs ?countryx.
    } order by desc(?year)

  • Wyniki:

• Informacje o najbliższych WiFi-AP w centrum Andory
  • dane: OpenMobileNetwork
  • zapytanie SPARQL

    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
    PREFIX lgdo: <http://linkedgeodata.org/ontology/>
    PREFIX owl: <http://www.w3.org/2002/07/owl#>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    PREFIX category: <http://dbpedia.org/resource/Category:>
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
    PREFIX dbpedia: <http://dbpedia.org/resource/>
    PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
    
    
    select ?wifiap ?SSID ?lat2 ?long2 where {
     
      service <http://dbpedia.org/sparql/> {
        <http://dbpedia.org/resource/Andorra_la_Vella> geo:lat ?lat1;
          geo:long ?long1.
      }
     
        
      ?wifiap a <http://www.openmobilenetwork.org/ontology/WiFiAP>;
        geo:lat ?lat2;
        geo:long ?long2;
        omn-owl:hasSSID ?SSID.
    }
    order by (xsd:float(?lat1 - ?lat2)*xsd:float(?lat1 - ?lat2) + xsd:float(?long1 - ?long2)*xsd:float(?long1 - ?long2))

  • wyniki